KvmChannel.idl

#ifndef __RADM_KVM_CHANNEL_IDL__
#define __RADM_KVM_CHANNEL_IDL__
 
#include <UserEvent.idl>
#include <VideoResolution.idl>
#include <KvmPort.idl>
 
module radm {
 
    interface KvmChannel {
 
        /** Channel meta data */
        structure Metadata {
            string label;         ///< Channel label
            int channelId;        ///< Index of channel in device's channel list
            int maxRemoteClients; ///< Maximum supported remote client count
            int maxLocalClients;  ///< Maximum supported local client count
            int maxUsbChannels;   ///< Maximum support USB channel count
        };
 
        /**
         * Get channel meta data
         *
         * @return Channel meta data
         */
        Metadata getMetadata();
 
        /**
         * Get KVM port currently attached to this channel
         *
         * If the device has more KVM ports than channels, the returned port may be empty,
         * as such devices detach the port from the channel when it's not in use.
         *
         * @return Attached KVM port
         */
        KvmPort getAttachedKvmPort();
 
        /**
         * Get local client connection status
         *
         * @return true if the device local port is currently connected to this channel, false otherwise
         */
        boolean hasLocalClient();
 
        /**
         * Get number of connected remote clients
         *
         * @return Total number of remote clients connected to this channel
         */
        int getConnectedRemoteClientCount();
 
        /**
         * Get video resolution and refresh rate
         *
         * @return Active video resolution and refresh rate of this channel
         */
        VideoResolution getVideoResolution();
 
        /** Event: Attached KVM port changed */
        valueobject AttachedKvmPortChangedEvent extends idl.Event {
            KvmPort newPort;
        };
 
        /** Event: Channel connection status changed */
        valueobject KvmSwitchEvent extends event.UserEvent {
            KvmPort port;                   ///< KVM port for operation
            boolean connected;              ///< whether port was switched on or off
            int connectedRemoteClients;     ///< Total number of connected remote clients
            boolean hasLocalClient;         ///< Whether the device local port is currently connected to this channel
        };
 
        /** Event: Video resolution on channel changed */
        valueobject VideoResolutionChangedEvent extends idl.Event {
            KvmPort port;                   ///< KVM port for operation
            VideoResolution newResolution;  ///< New video resolution
        };
    };
 
}
 
#endif //__RADM_KVM_CHANNEL_IDL__