TerminalBlock.idl

#ifndef __RADM_TERMINALBLOCK_IDL__
#define __RADM_TERMINALBLOCK_IDL__
 
#include <UserEvent.idl>
 
/** Radm Model */
module radm {
 
    /** %TerminalBlock interface */
    interface TerminalBlock {
        constant int ERR_INVALID_ARGUMENT = 1;      ///< Any argument was invalid
        constant int ERR_BUSY_PULSING = 2;          ///< Settings can't be applied because previous pulse is still active
 
        /** KVM access control based on input status */
        enumeration InputMode {
            FULL_ACCESS,    ///< Allow full KVM access
            VIDEO_ONLY,     ///< Allow video-only KVM access
            NO_ACCESS       ///< Do not allow KVM access
        };
 
        /** Output Options */
        enumeration OutputMode {
            DEVICE_OFF,     ///< Output off
            DEVICE_ON,      ///< Output on
            DEVICE_BLINK,   ///< Output blinking
            DEVICE_PULSE,   ///< Output pulse
            KVMSTATUS       ///< Output on/off based on KVM port status
        };
 
        /** Input Status */
        enumeration InputStatus {
            OPEN,
            CLOSED
        };
 
        /** Output Status */
        enumeration OutputStatus {
            OFF,
            ON,
            BLINKING
        };
 
        structure Settings {
            boolean inputEnabled;           ///< Enable KVM access control based on input status.
            InputStatus activeInputState;   ///< Input status is used to control KVM access.
            InputMode inputRemote;          ///< KVM access control applied to remote user.
            InputMode inputLocal;           ///< KVM access control applied to local user.
            boolean outputEnabled;          ///< Enable output
            OutputMode outputMode;          ///< Output options
            int blinkPulseInterval;         ///< Interval (in half seconds) for blink/pulse.
            boolean kvmIdleOff;             ///< Only effective in KVMSTATUS option:
                                            ///<   true:  output off when KVM idle, output on otherwise
                                            ///<   false: output on when KVM idle, output off otherwise
        };
 
        /** Terminal Block Status including input and output */
        structure Status {
            InputStatus inputStatus;
            OutputStatus outputStatus;
        };
 
        /**
         * Retrieve terminal block settings
         *
         * @return Settings
         */
        Settings getSettings();
 
        /**
         * Change terminal block settings
         *
         * @param settings  New terminal block settings
         *
         * @return 0 on success
         * @return 1 if any setting value was invalid
         * @return 2 if a previous pulse is still active
         */
        int setSettings(in Settings settings);
 
        /**
         * Retrieve terminal block status
         *
         * @return Terminal block status
         */
        Status getStatus();
 
        /** Event: The terminal block settings have changed */
        valueobject SettingsChangedEvent extends event.UserEvent {
            Settings oldSettings;      ///< Settings before change
            Settings newSettings;      ///< Settings after change
        };
 
        /** Event: The terminal block status have changed */
        valueobject StatusChangedEvent extends event.UserEvent {
            Status oldStatus;          ///< Status before change
            Status newStatus;          ///< Status after change
        };
    };
}
 
#endif //__TERMINALBLOCK_TERMINALBLOCK_IDL__