SerialAccessPort.idl

#ifndef __RADM_SERIAL_ACCESS_PORT_IDL__
#define __RADM_SERIAL_ACCESS_PORT_IDL__
 
#include <Event.idl>
#include <UserEvent.idl>
#include <AccessPort.idl>
 
module radm {
 
    interface SerialAccessPort extends AccessPort {
 
        /** Serial device interface type */
        enumeration DeviceInterfaceType {
            DEV_IFTYPE_AUTO,                    ///< auto detect
            DEV_IFTYPE_DTE,                     ///< DTE (Data Terminal Equipment) device
            DEV_IFTYPE_DCE                      ///< DCE (Data Communications Equipment) device
        };
 
        /** Terminal emulation type */
        enumeration Emulation {
            VT100,
            VT220,
            VT320,
            ANSI
        };
 
        /** Character encoding */
        enumeration Encoding {
            DEFAULT,
            US_ASCII,
            ISO_8859_1,
            ISO_8859_15,
            UTF_8,
            SHIFT_JIS,
            EUC_JP,
            EUC_CN,
            EUC_KR,
            EIGHTBIT_ASCII
        };
 
        /** Flow control type */
        enumeration FlowControl {
            FLOW_CTRL_NONE,             ///< No flow control
            FLOW_CTRL_HARDWARE,         ///< Hardware flow control
            FLOW_CTRL_SOFTWARE          ///< Software flow control
        };
 
        /** Parity mode */
        enumeration Parity {
            PARITY_NONE,        ///< No parity (implies 8 data bits)
            PARITY_ODD,         ///< Odd parity (implies 7 data bits)
            PARITY_EVEN         ///< Even parity (implies 7 data bits)
        };
 
        enumeration EscapeKeyModifier {
            NO_MODIFIER,
            CONTROL
        };
 
        structure ExitCommandItem {
            string command;     ///< Command to send
            int delay;          ///< Delay after sending the command (in s)
        };
 
        structure Settings {
            string name;                            ///< Port name
            Emulation emulation;                    ///< Terminal emulation setting
            Encoding encoding;                      ///< Character encoding
            DeviceInterfaceType devIfType;          ///< Interface type override
            int baudRate;                           ///< Baud rate
            Parity parity;                          ///< Parity mode
            FlowControl flowCtrl;                   ///< Flow control mode
            int stopBits;                           ///< Number of stop bits (1 or 2)
            int txCharDelayMs;                      ///< Delay after each transmitted character (in ms)
            int txLineDelayMs;                      ///< Delay after each transmitted line (in ms)
            int breakDurationMs;                    ///< Duration of transmitted break conditions (in ms)
            boolean multiWriteMode;                 ///< Whether multiple port accessors can write to the same port simultaneously
            boolean alwaysActive;                   ///< Whether data should be read and buffered even if no client is currently connected
            string escChar;                         ///< Character for going from terminal to command mode (at most 1 character)
            EscapeKeyModifier escKeyModifier;       ///< Key modifier for going from terminal to command mode
            vector<ExitCommandItem> exitCommand;    ///< Sequence of commands to send when a client disconnects
            int sshDpaPort;                         ///< SSH port for directly accessing this serial port (in case SSH-DPA is enabled)
        };
 
        /**
         * Get the parent device of this port
         *
         * Note: In practice, an instance of {@link DsamDevice} will be returned.
         *
         * @return Parent device
         */
        Device getParent();
 
        /**
         * Get port settings
         *
         * @return Port settings
         */
        Settings getSettings();
 
        /**
         * Set new port settings
         *
         * @param settings New settings
         *
         * @return 0 on success
         * @return 1 if any setting value is invalid
         */
        int setSettings(in Settings settings);
 
        /**
         * Get automatically detected interface type
         *
         * @return Detected interface type
         */
        DeviceInterfaceType getDetectedInterfaceType();
 
        /** Event: The port settings have changed */
        valueobject SettingsChangedEvent extends event.UserEvent {
            Settings oldSettings;   ///< Port settings before change
            Settings newSettings;   ///< Port settings after change
        };
 
        /** Event: The detected type has changed */
        valueobject DetectedInterfaceTypeChangedEvent extends idl.Event {
            DeviceInterfaceType oldIfType;   ///< Detected interface type before change
            DeviceInterfaceType newIfType;   ///< Detected interface type after change
        };
    };
}
 
#endif //__RADM_SERIAL_ACCESS_PORT_IDL__