Rdm.idl

#ifndef __RDM_RDM_IDL__
#define __RDM_RDM_IDL__
 
#include <UserEvent.idl>
 
/**
 * Rdm Model
 */
module rdm {
    interface Rdm {
        constant int ERR_INVALID_ARGUMENT = 1;
 
        enumeration ManagementState {
            UNMANAGED,                  ///< Device is not under CC-SG management
            MANAGED,                    ///< Device is under active CC-SG management
            MANAGED_CC_UNREACHABLE      ///< CC-SG management was configured for the device, but the server is not reachable
        };
 
        /** CC-SG management state */
        structure State {
            ManagementState mgmtState;      ///< Management state
            boolean directAccessAllowed;    ///< Whether direct access (local device login) is allowed
            string ccIpAddress;             ///< CC-SG IPv4 address
            string ccIpv6Address;           ///< CC-SG IPv6 address
        };
 
        /** CC-SG management settings */
        structure Settings {
            int discoveryPort;      ///< Port number for CC-SG connection
            boolean useEncryption;  ///< Whether to encrypt management communication
        };
 
        /**
         * Get CC-SG management state
         *
         * @return Management state
         */
        State getState();
 
        /**
         * Get CC-SG management settings
         *
         * @return Management settings
         */
        Settings getSettings();
 
        /**
         * Set CC-SG management settings
         *
         * @param settings New settings
         *
         * @return 0 on success
         * @return 1 if any setting value was invalid
         */
        int setSettings(in Settings settings);
 
        /**
         * Stop CC-SG management for this device
         *
         * This operation is valid only if the device is under CC-SG
         * management, but the CC server is unreachable.
         *
         * @return 0 on success
         * @return 1 if the device is not in MANAGED_CC_UNREACHABLE state
         */
        int stopManagement();
 
        /** Event: CC-SG management settings have changed */
        valueobject SettingsChangedEvent extends event.UserEvent {
            Settings oldSettings;   ///< Settings before change
            Settings newSettings;   ///< Settings after change
        };
 
        /** Event: CC-SG management was stopped */
        valueobject ManagementStoppedEvent extends event.UserEvent {};
 
        /** Event: CC-SG management state has changed */
        valueobject StateChangedEvent extends idl.Event {
            State oldState;     ///< State before change
            State newState;     ///< State after change
        };
    };
}
 
#endif