PowerDevice.idl

#ifndef __RADM_POWER_DEVICE_IDL__
#define __RADM_POWER_DEVICE_IDL__
 
#include <Device.idl>
#include <OutletPort.idl>
 
module radm {
    interface PowerDevice extends Device {
        constant int ERR_READONLY_VALUE         = 10; ///< A read-only value was changed
 
        constant int ERR_SNMP_MIB_MISMATCH      = 101; ///< The PDU's SNMP MIB is incompatible
        constant int ERR_SNMP_TIMEOUT           = 102; ///< SNMP response timeout
        constant int ERR_SNMP_COMM_FAILURE      = 103; ///< SNMP communication failed
        constant int ERR_SNMP_NOACCESS          = 104; ///< No access to SNMP resource
        constant int ERR_SNMP_AUTHORIZATION     = 105; ///< SNMP authorization error
        constant int ERR_SNMP_INTERNAL_PROBLEM  = 106; ///< An internal error was encountered during SNMP communication
 
        enumeration SnmpSecurityLevel {
            NO_AUTH_NO_PRIV,  ///< no authentication, no privacy
            AUTH_NO_PRIV,    ///< authentication, no privacy
            AUTH_PRIV       ///< authentication, privacy
        };
 
        enumeration SnmpAuthProtocol {
            MD5,       ///< MD5
            SHA1,      ///< SHA-1
            SHA224,    ///< SHA-224
            SHA256,    ///< SHA-256
            SHA384,    ///< SHA-384
            SHA512     ///< SHA-512
        };
 
        enumeration SnmpPrivProtocol {
            DES,          ///< DES
            AES128,       ///< AES-128
            AES192,       ///< AES-192
            AES256,       ///< AES-256
            AES192_3DES,  ///< AES-192 with key extension (3DES)
            AES256_3DES   ///< AES-256 with key extension (3DES)
        };
 
        enumeration DeviceType {
            RARITAN,
            SERVER_TECHNOLOGY
        };
 
        structure Settings {
            DeviceType type;                ///< Type of PDU
            string name;                    ///< PDU name
            string host;                    ///< Network host name of PDU, read-only after initial creation
            int port;                       ///< SNMP network port
            boolean useSnmpV3;              ///< Whether to use SNMPv3 instead of SNMP v1/2c
            string community;               ///< SNMP write community string (only valid for SNMP v1/2c)
            string userName;                ///< SNMP v3 user name (only valid for SNMP v3)
            SnmpSecurityLevel secLevel;     ///< SNMP security level (only valid for SNMP v3)
            SnmpAuthProtocol authProtocol;  ///< SNMP authentication protocol (only valid for SNMP v3)
            string authPass;                ///< SNMP authentication password (only valid for SNMP v3)
            SnmpPrivProtocol privProtocol;  ///< SNMP privacy protocol (only valid for SNMP v3)
            string privPass;                ///< SNMP privacy password (only valid for SNMP v3)
        };
 
        /**
         * Get device settings
         *
         * @return Device settings
         */
        Settings getSettings();
 
        /**
         * Set settings for this device
         *
         * @param settings New settings to set
         *
         * @return 0 on success
         * @return 1 if any argument is invalid
         * @return 10 when changing any read-only value
         */
        int setSettings(in Settings settings);
 
        /**
         * Resume communication to this PDU
         *
         * @return 0 on success
         * @return 101 if the given host name was not found
         * @return 102 if the SNMP communication timed out
         * @return 103 if there was any other failure during SNMP communication
         * @return 104 if the PDU responded with 'no access'
         * @return 105 if the SNMP authorization failed
         * @return 106 if there was an internal problem during SNMP communication
         */
        int resume();
 
        /**
         * Get outlets belonging to this PDU
         *
         * @return List of outlet ports
         */
        vector<OutletPort> getOutletPorts();
 
        /** Event: Device settings have changed */
        valueobject SettingsChangedEvent extends event.UserEvent {
            Settings oldSettings;           ///< Settings before change
            Settings newSettings;           ///< Settings after change
        };
    };
}
 
#endif // __RADM_POWER_DEVICE_IDL__