PowerDeviceManager.idl

#ifndef __RADM_POWER_DEVICE_MANAGER_IDL__
#define __RADM_POWER_DEVICE__MANAGER_IDL__
 
#include <UserEvent.idl>
#include <PowerDevice.idl>
 
module radm {
 
    interface PowerDeviceManager {
        constant int ERR_INVALID_ARGUMENT     = 1; ///< Invalid argument
        constant int ERR_PDU_ALREADY_EXISTS   = 2; ///< A PDU with that host name already exists
        constant int ERR_MAX_PDUS_REACHED     = 3; ///< Maximum number of pdus reached
        constant int ERR_PDU_NOT_FOUND        = 4; ///< A PDU with that host name does not exist
 
        structure Settings {
            int powerCycleDelay; ///< Delay between turning off and turning on in power cycle (in seconds)
        };
 
        /**
         * Get configured power devices
         *
         * @return Map of configured power devices, keyed by host name
         */
        map<string, PowerDevice> getPowerDevices();
 
        /**
         * Add a new power device (PDU)
         *
         * @param settings Settings for creating the new power device
         *
         * @return 0 on success
         * @return 1 if any given setting was invalid
         * @return 2 if a PDU with that host name or name already exists
         * @return 3 if the maximum number of PDUs is reached
         * @return 101..106 in case of an SNMP error during PDU connection (see constants in {@link PowerDevice}
         */
        int addPowerDevice(in PowerDevice.Settings settings);
 
        /**
         * Remove the given power device (PDU)
         *
         * @param host Host name of the PDU to be removed
         *
         * @return 0 on success
         * @return 4 if there is no PDU with that host name
         */
        int deletePowerDevice(in string host);
 
        /**
         * Get global power device settings
         *
         * @return Settings
         */
        Settings getSettings();
 
        /**
         * Set global power device settings
         *
         * @param settings New settings
         *
         * @return 0 on success
         * @return 1 if any setting was invalid
         */
        int setSettings(in Settings settings);
 
        /** Event: A power device was added or removed */
        valueobject PowerDeviceChangedEvent extends event.UserEvent {
            map<string, PowerDevice> powerDevices;  ///< Map of power devices after change
        };
 
        /** Event: A power device was added */
        valueobject PowerDeviceAddedEvent extends PowerDeviceChangedEvent {
            PowerDevice device;     ///< Newly created power device
        };
 
        /** Event: A power device was removed */
        valueobject PowerDeviceRemovedEvent extends PowerDeviceChangedEvent {
            string deviceId;        ///< ID of the removed power device
            string deviceName;      ///< Name of the removed power device
        };
 
        /** Event: Manager settings changed */
        valueobject SettingsChangedEvent extends event.UserEvent {
            Settings oldSettings;   ///< Settings before change
            Settings newSettings;   ///< Settings after change
        };
    };
}
 
#endif //__RADM_POWER_DEVICE_MANAGER_IDL__