OutletPort.idl

#ifndef __RADM_OUTLET_IDL__
#define __RADM_OUTLET_IDL__
 
#include <Event.idl>
#include <UserEvent.idl>
#include <BasePort.idl>
#include <Device.idl>
 
module radm {
 
    interface OutletPort extends BasePort {
        constant int ERR_PDU_NOT_ACTIVE = 10;
 
        enumeration PowerState {
            UNKNOWN,
            OFF,
            ON
        };
 
        /**
         * Get current power state of this port
         *
         * @return Power state
         */
        PowerState getState();
 
        /**
         * Change the power state of this port
         *
         * @param op Operation to execute
         *
         * @return 0 on success
         * @return 10 if PDU is not active
         * @return 101..106 if SNMP communication failed (see constants in {@link PowerDevice})
         */
        int doPowerOperation(in PowerOperation op);
 
        /**
         * Get parent device of this port
         *
         * Note: In practice a {@link PowerDevice} instance will be returned.
         *
         * @return Parent device
         */
        Device getParent();
 
        /**
         * Get port this port is associated with
         *
         * Note: In practice a {@link AccessPort} instance will be returned if an association is present.
         *
         * @return associated port
         */
        BasePort getAssociatedAccessPort();
 
        /** Event: The outlet power state has changed */
        valueobject PowerStateChangedEvent extends event.UserEvent  {
            PowerState oldState;    ///< Power state before change
            PowerState newState;    ///< Power state after change
        };
 
        /** Event: The associated port has changed */
        valueobject AssociatedAccessPortChangedEvent extends idl.Event {
            BasePort oldAssociatedPort;    ///< Associated port before change
            BasePort newAssociatedPort;    ///< Associated port after change
        };
 
        /** Event: A power operation was started */
        valueobject PowerOperationEvent extends event.UserEvent {
            PowerOperation op;   ///< PowerOperation
        };
    };
}
 
#endif //__RADM_OUTLET_IDL__