LocalPort.idl

#ifndef __RADM_LOCALPORT_IDL__
#define __RADM_LOCALPORT_IDL__
 
#include <Event.idl>
#include <KeyboardLayout.idl>
#include <KvmPort.idl>
#include <LocalMonitor.idl>
 
module radm {
 
    /** Interface for local user interface */
    interface LocalPort {
        constant int ERR_INVALID_ARGUMENT = 1;  ///< Invalid parameters
        constant int ERR_ACCESS_DENIED = 2;     ///< Port access denied
 
        /** Key combinations for switching from KVM port to local UI */
        enumeration HotKey {
            DOUBLE_SCROLL_LOCK,
            DOUBLE_NUM_LOCK,
            DOUBLE_CAPS_LOCK,
            DOUBLE_LEFT_ALT_KEY,
            DOUBLE_LEFT_SHIFT_KEY,
            DOUBLE_LEFT_CTRL_KEY
        };
 
        /** Keys for switching from local UI to KVM port */
        enumeration ConnectKey {
            DISABLED,
            LEFT_ALT_KEY,
            LEFT_SHIFT_KEY,
            LEFT_CTRL_KEY
        };
 
        /** Authentication modes for local UI */
        enumeration LocalUserAuthMode {
            COMMON,         ///< Use authentication as configured (local/LDAP/Radius)
            NONE            ///< Do not use authentication
        };
 
        /** Local port settings */
        structure Settings {
            boolean enabled;                ///< Whether local port UI is enabled or not
            KeyboardLayout keyboardLayout;  ///< Keyboard language to use
            HotKey hotkey;                  ///< Key combination to use for going back from KVM port to UI
            ConnectKey connectkey;          ///< Key to use to trigger switch to KVM port
            LocalUserAuthMode authMode;     ///< Authentication mode for local UI
            boolean ignoreCCManagedMode;    ///< Whether to allow local UI login under CC-SG management
        };
 
        /**
         * Get monitor attached to local port
         *
         * @return Local monitor instance
         */
        LocalMonitor getMonitor();
 
        /**
         * Get local port settings
         *
         * @return Port settings
         */
        Settings getSettings();
 
        /**
         * Set local port settings
         *
         * @param settings New settings
         *
         * @return 0 if OK
         * @return 1 if any setting was invalid
         */
        int setSettings(in Settings settings);
 
        /**
         * Switch local port to show given KVM port
         *
         * @param sessionId ID of the session under which to execute the switch
         * @param port      Port to switch to
         *
         * @return 0 if OK
         * @return 1 if session ID was invalid
         * @return 2 if session is not allowed to access the given port
         */
        int switchToPort(in int sessionId, in KvmPort port);
 
        /** Event: Local port settings have changed */
        valueobject SettingsChangedEvent extends event.UserEvent {
            Settings oldSettings;           ///< Settings before change
            Settings newSettings;           ///< Settings after change
        };
    };
 
}
 
#endif //__RADM_LOCALMONITOR_IDL__