KvmPort.idl

#ifndef __RADM_KVM_PORT_IDL__
#define __RADM_KVM_PORT_IDL__
 
#include <UserEvent.idl>
#include <AccessPort.idl>
#include <UsbProfileSettings.idl>
#include <VideoResolution.idl>
 
module radm {
 
    interface KvmPort extends AccessPort {
        constant int ERR_USB_RECONFIG_NOT_ALLOWED_BUSY = 20;
 
        enumeration PortType {
            KVM,
            BLADEPORT,
            BLADECHASSIS
        };
 
        structure Capabilities {
            PortType type;              ///< Port type of this port
            boolean absoluteMouse;      ///< Absolute mouse mode can be used on this port
            boolean virtualMedia;       ///< Virtual media / mass storage can be used on this port
            boolean usbSettings;        ///< The port supports using the 'usb' part of {@link Settings}.
            boolean usbProfiles;        ///< The port supports setting active and selected USB profiles in {@link Settings}.
            boolean digitalVideo;       ///< The port has a digital video input
            boolean ddc;                ///< The port supports EDID communication towards the target and thus supports setting preferred resolution in {@link Settings}.
            boolean audio;              ///< The port has audio support
            boolean smartCard;          ///< The port has smart card support
            boolean dviCompatMode;      ///< The port has an HDMI video input and thus supports setting DVI compat mode in {@link Settings}.
            boolean cim;                ///< CIMs can be attached to this port
            boolean blade;              ///< The port has support for blade server configuration
        };
 
        /** USB settings for devices without usbProfiles capability */
        structure UsbSettings {
            UsbProfileSettings profile; ///< USB settings handled by profiles on devices with usbProfiles capability, see {@link UsbProfileSettings}
            boolean overrideVendor;     ///< Whether to override the default (Raritan) USB vendor and product ID with that of a locally attached device
            boolean usbAudio;           ///< Whether to enable USB audio
        };
 
        enumeration EdidSource {
            STANDARD,   ///< Use built-in EDID data
            CUSTOM,     ///< Use custom EDID data previously uploaded
            LOCAL       ///< Use EDID data of a locally attached monitor
        };
 
        enumeration CimNamingMode {
            CIM_TO_PORT,            ///< Transfer CIM name to port name
            PORT_TO_CIM_ONCE,       ///< Transfer port name to CIM name on next connection
            PORT_TO_CIM_ALWAYS      ///< Transfer port name to CIM name on every connection
        };
 
        /** Information about group membership of this port */
        valueobject GroupInfo {
            string groupId;         ///< ID of the group containing this port
            int positionInGroup;    ///< Position inside the group (index into group member list)
        };
 
        /** Information about group membership in case this port is part of a multi-monitor group */
        valueobject MultiMonitorGroupInfo extends KvmPort.GroupInfo {
            boolean isPrimary;          ///< This port is considered the primary monitor of the group
            int horizontalPosition;     ///< Horizontal position inside the monitor grid formed by the group
            int verticalPosition;       ///< Vertical position inside the monitor grid formed by the group
        };
 
        /** Information about a CIM connected to a port */
        valueobject CimInfo {
            string cimName;         ///< Name as configured in the CIM
            string serialNumber;    ///< CIM serial number
            string cimType;         ///< CIM model
            string fwVersion;       ///< Firmware version
            string hwVersion;       ///< Hardware version
        };
 
        structure IntelligentMouseSettings {
            boolean manualSync;                 ///< ???
            float manualAcceleration;           ///< ???
            int manualThreshold;                ///< ???
            int accumulationPeriod;             ///< Period (in ms) over which to accumulate incoming mouse movements until sending them to the target (0 = no accumulation)
        };
 
        /** Settings for digital (non-CIM) ports */
        structure DigitalPortSettings {
            int edidCycleTime;                      ///< Cycle time for hot-plug detect signal on EDID changes (in ms, available for ddc capability)
            boolean vgaMode;                        ///< Whether to treat the the video input as originating from an analog video source -
                                                    ///< if enabled, noise filters and color range conversion are used
            int vgaGainBoost;                       ///< How aggressively color range conversion should be done in VGA mode on a 0..9 scale
            boolean audioCompensation;              ///< Whether to compensate for issues in HDMI audio connection
        };
 
        /** Settings for CIM-based ports */
        structure CimPortSettings {
            boolean dosResolutionCompensation;      ///< Whether to compensate for issues with 640x480 or 720x400 video resolutions
            boolean offsetCompensation;             ///< Whether to compensate for non-centered video output
            CimNamingMode namingMode;               ///< Name transfer behavior when connecting a CIM to this port
        };
 
        structure Settings {
            string name;                            ///< Port name
            VideoResolution preferredResolution;    ///< Preferred video resolution for this port (available for ddc capability)
            EdidSource preferredResolutionSource;   ///< Source of EDID data for preferred resolution (available for ddc capability)
            boolean dviCompatMode;                  ///< Use DVI instead of HDMI EDID data (available for dviCompatMode capability)
            boolean videoPortrait;                  ///< Whether to interpret the video signal in landscape or portrait orientation
            boolean videoThrottle;                  ///< Cap client frame rate at half of incoming video frame rate
            DigitalPortSettings digital;            ///< Digital port settings (not available for cim capabilitty)
            CimPortSettings cim;                    ///< CIM-based port settings (available for cim capability)
            IntelligentMouseSettings mouse;         ///< Settings for intelligent mouse mode
            UsbSettings usb;                        ///< USB settings (available for usbSettings capability)
            vector<int> selectedProfiles;           ///< IDs of USB profiles to be available for this port (available for usbProfiles capability)
            int activeProfile;                      ///< ID of active USB profile (available for usbProfiles capability)
            int preferredProfile;                   ///< ID of preferred USB profile (available for usbProfiles capability)
        };
 
        /**
         * Get port capabilities
         *
         * @return Port capabilities
         */
        Capabilities getCapabilities();
 
        /**
         * Get port settings
         *
         * @return Port settings
         */
        Settings getSettings();
 
        /**
         * Set port settings
         *
         * @param settings New settings
         *
         * @return 0 on success
         * @return 1 if any setting was invalid
         * @return 20 if USB settings could not be changed due to the port currently being in use
         */
        int setSettings(in Settings settings);
 
        /**
         * Get information about port group membership
         *
         * @return Group information object in case this port is part of a group
         */
        GroupInfo getGroupInfo();
 
        /**
         * Get information about a CIM connected to the port
         *
         * @return CIM information object in case a CIM is connected to the port
         */
        CimInfo getCimInfo();
 
        /** Event: The port capabilities have changed */
        valueobject CapabilitiesChangedEvent extends idl.Event {
            Capabilities oldCapabilities;   ///< Capabilities before change
            Capabilities newCapabilities;   ///< Capabilities after change
        };
 
        /** Event: The port settings have changed */
        valueobject SettingsChangedEvent extends event.UserEvent {
            Settings oldSettings;   ///< Port settings before change
            Settings newSettings;   ///< Port settings after change
        };
 
        /** Event: The port group has changed */
        valueobject GroupInfoChangedEvent extends event.UserEvent {
            GroupInfo oldGroupInfo;   ///< Group information before change
            GroupInfo newGroupInfo;   ///< Group information after change
        };
 
        /** Event: The port ciminfo have changed */
        valueobject CimInfoChangedEvent extends idl.Event {
            CimInfo oldCimInfo;   ///< CIM information before change
            CimInfo newCimInfo;   ///< CIM information after change
        };
 
        /** Event: Active USB profile has changed */
        valueobject ActiveUsbProfileChangedEvent extends idl.Event {
            string profileName;   ///< Profile name
            long profileKey;      ///< Profile key
        };
 
    };
 
}
 
#endif //__RADM_KVM_PORT_IDL__