KeySetManager.idl

#ifndef __RADM_KEY_SET_MANAGER_IDL__
#define __RADM_KEY_SET_MANAGER_IDL__
 
#include <KeyboardLayout.idl>
#include <UserEvent.idl>
 
module radm {
    interface KeySetManager {
        constant int ERR_INVALID_ARGUMENT = 1;
        constant int ERR_NAME_ALREADY_USED = 2;
 
        /** Structure representing a key set (a named group of keyboard key codes) */
        structure KeySet {
            int id;                         ///< Unique ID of this key set
            string name;                    ///< Key set name
            KeyboardLayout keyboardLayout;  ///< Keyboard layout to be assumed for this key set
                                            ///< (traditional and simplified Chinese are not supported)
            vector<int> keys;               ///< Scan codes of keys in the key sets (for definition of scan codes, see KVM client SDK)
        };
 
        /**
         * Get all configured key sets
         *
         * @return List of configured key sets
         */
        vector<KeySet> getAllKeySets();
 
        /**
         * Get a particular configured key set
         *
         * @param id ID of the desired key set
         * @param keyset Returned key set
         *
         * @return 0 on success
         * @return 1 if the ID could not be found
         */
        int getKeySetById(in int id, out KeySet keyset);
 
        /**
         * Add a new key set
         *
         * @param keyset Key set to be added
         *
         * @return 0 on success
         * @return 1 if any key set parameter is invalid
         * @return 2 if the provided key set name already is used by another key set
         */
        int addKeySet(in KeySet keyset);
 
        /**
         * Change a given key set
         *
         * @param keyset Key set to be updated (matched against existing key set by ID)
         *
         * @return 0 on success
         * @return 1 if no key set with the given ID was found, or if any other key set paraneter is invalid
         * @return 2 if the provided key set name already is used by another key set
         */
        int updateKeySet(in KeySet keyset);
 
        /**
         * Delete a key set
         *
         * @param id ID of the key set to be deleted
         *
         * @return 0 on success
         * @return 1 if no key set with the given ID was found
         */
        int deleteKeySet(in int id);
 
        /** Event: List of configured key sets has changed */
        valueobject KeySetsChangedEvent extends event.UserEvent {
            vector<KeySet> newKeySets;  ///< new KeySets after change
        };
    };
}
 
#endif // __RADM_KEY_SET_MANAGER_IDL__