DsamDeviceManager.idl

#ifndef __RADM_DSAM_DEVICE_MANAGER_IDL__
#define __RADM_DSAM_DEVICE_MANAGER_IDL__
 
#include <DsamDevice.idl>
#include <SerialAccessPort.idl>
#include <UserEvent.idl>
 
module radm {
    interface DsamDeviceManager {
        constant int ERR_INVALID_ARGUMENT = 1;
 
        /**
         * %Firmware update history status
         */
        enumeration UpdateHistoryStatus {
            SUCCESSFUL,                     ///< The update was successfully completed
            FAILED,                         ///< The update failed
            INCOMPLETE                      ///< The update was not completed
        };
 
        /**
         * DSAM firmware update history entry
         */
        structure UpdateHistoryEntry {
            int port;                       ///< Index of port the DSAM was connected to
            string serialno;                ///< DSAM serial number
            time timestamp;                 ///< Timestamp when the update was started
            string oldVersion;              ///< Previous firmware version
            string imageVersion;            ///< Firmware version of update image
            UpdateHistoryStatus status;     ///< Update status
        };
 
        /**
         * Get DSAM devices connected to the device
         *
         * @return List of connected DSAM devices
         */
        vector<DsamDevice> getDsamDevices();
 
        /**
         * Get version of the DSAM firmware available for update
         *
         * @return Version number string of the available DSAM firmware
         */
        string getAvailableFirmwareVersion();
 
        /**
         * Fetch the DSAM firmware update history.
         *
         * @return DSAM firmware update history entries
         */
        vector<UpdateHistoryEntry> getUpdateHistory();
 
        /**
         * Start firmware update on the given devices
         *
         * @param dsams DSAM devices to update
         */
        void startFirmwareUpdate(in vector<DsamDevice> dsams);
 
        /**
         * Get serial device keyword mapping
         *
         * An alert is sent in the serial protocol whenever a configured
         * keyword is encountered in the serial port data.
         *
         * @return Keyword mapping, using the keywords as map keys and
         *         the serial ports the keyword is configured for as value
         */
        map<string, vector<SerialAccessPort>> getKeywordMapping();
 
        /**
         * Set serial device keyword mapping
         *
         * The following constraints apply:
         * - There must not be more than 16 keywords per port
         * - Ports for a given keyword must be unique (no duplicates)
         *
         * @param mapping New keyword mapping, using keyword as key and
         *                serial ports the keyword is configured for as value
         *
         * @return 0 on success
         * @return 1 if the mapping is invalid
         */
        int setKeywordMapping(in map<string, vector<SerialAccessPort>> mapping);
 
        /** Event: Connected DSAM devices list has changed */
        valueobject DeviceChangedEvent extends idl.Event {
            vector<DsamDevice> dsamList;    ///< List of connected DSAM devices after change
        };
 
        /** Event: A DSAM device was connected */
        valueobject DeviceAttachedEvent extends DeviceChangedEvent {
            DsamDevice device;      ///< Newly connected DSAM device
        };
 
        /** Event: A DSAM device was disconnected */
        valueobject DeviceRemovedEvent extends DeviceChangedEvent {
            string deviceId;        ///< ID of disconnected DSAM
            string serialNumber;    ///< Serial number of disconnected DSAM
        };
 
        /** Event: The keyword mapping was changed */
        valueobject KeywordMappingChangedEvent extends event.UserEvent {
            map<string, vector<SerialAccessPort>> oldMapping;   ///< Mapping before change
            map<string, vector<SerialAccessPort>> newMapping;   ///< Mapping after change
        };
    };
}
 
#endif // __RADM_DSAM_DEVICE_MANAGER_IDL__