Device.idl

#ifndef __RADM_DEVICE_IDL__
#define __RADM_DEVICE_IDL__
 
#include <UserEvent.idl>
 
module radm {
    interface Device {
        constant int ERR_INVALID_ARGUMENT = 1;
        constant int ERR_NOT_SUPPORTED = 2;
 
        enumeration State {
            UNKNOWN,    ///< Device state was not yet determined
            INACTIVE,   ///< Device is inactive / not connected
            ACTIVE      ///< Device is active / connected
        };
 
        structure Metadata {
            string serialNumber;    ///< Device serial number
            string product;         ///< Device product family
            string model;           ///< Device model
            string fwVersion;       ///< Device firmware version (if applicable)
            string hwVersion;       ///< Device hardware version (if applicable)
            string macAddress;      ///< Device MAC address (if applicable)
            string privilegeArg;    ///< Privilege argument for this device in case a privilege is required to access it
            string uid;             ///< Unique identifier for this device
            int idx;                ///< Index of the device in its respective list
        };
 
        /**
         * Get device state
         *
         * @return Device state
         */
        State getState();
 
        /**
         * Get device meta data
         *
         * @return Device meta data
         */
        Metadata getMetadata();
 
        /**
         * Get device name
         *
         * @return Device name
         */
        string getName();
 
        /**
         * Set device name
         *
         * @param name New name
         *
         * @return 0 on success
         * @return 1 if the given name is invalid
         * @return 2 if the device name can not be changed
         */
        int setName(in string name);
 
        /** Event: The device name has changed */
        valueobject NameChangedEvent extends event.UserEvent {
            string oldName;         ///< Name before change
            string newName;         ///< Name after change
        };
 
        /** Event: The device state has changed */
        valueobject StateChangedEvent extends idl.Event {
            State oldState;         ///< State before change
            State newState;         ///< State after change
            string name;
        };
    };
 
}
 
#endif //__RADM_DEVICE_IDL__